mirror of
https://git.dev.opencascade.org/repos/occt.git
synced 2025-04-03 17:56:21 +03:00
ad8b073e19
Boolean Operations:
1. Face/Face intersection post treatment - Unify vertices put on the section curves, which were rejected as existing ones, with the vertices of edges by which these section curves have been rejected.
2. Extend Warnings Reporting system of Boolean operations with the new warnings:
- BOPAlgo_AlertIntersectionOfPairOfShapesFailed - to be added when the intersection of pair of sub-shapes of the arguments has failed;
- BOPAlgo_AlertBuildingPCurveFailed - to be added when the building of the 2D curve of the edge on face has failed;
- BOPAlgo_AlertAcquiredSelfIntersection - to be added when the positioning and tolerances of the arguments leads to creation of self-interfered shapes.
These new warnings allow completing the operation even if intersection of some of the sub-shapes or building of some of the PCurves has failed. Moreover, they allow getting the pairs of sub-shapes on which the intersection/projection has failed, providing the user ability to analyze the intersection results.
Note that if some of these warnings appear, the result of the operation should be carefully analyzed for validity.
3. Print messages for the Warnings/Errors met during checking of the shape on self-intersection ("bopcheck" command).
79 lines
3.5 KiB
CMake
79 lines
3.5 KiB
CMake
# OCCT resource files generation
|
|
|
|
macro (OCCT_GENERATE_CONTENT_ONLY CurrentResource)
|
|
set (RESOURCE_FILES)
|
|
set (isResDirectory FALSE)
|
|
if (IS_DIRECTORY "${CMAKE_SOURCE_DIR}/src/${CurrentResource}")
|
|
file (STRINGS "${CMAKE_SOURCE_DIR}/src/${CurrentResource}/FILES" RESOURCE_FILES)
|
|
set (CurrentResource_Directory "${CurrentResource}")
|
|
set (isResDirectory TRUE)
|
|
else()
|
|
get_filename_component (CurrentResource_Name "${CurrentResource}" NAME)
|
|
list (APPEND RESOURCE_FILES "res:::${CurrentResource_Name}")
|
|
get_filename_component (CurrentResource_Directory "${CurrentResource}" DIRECTORY)
|
|
endif()
|
|
|
|
# Add current toolkit into RESOURCE_TOOLKITS array to copy it to the BUILD directory
|
|
list (APPEND RESOURCE_TOOLKITS "${CurrentResource_Directory}")
|
|
list (REMOVE_DUPLICATES RESOURCE_TOOLKITS)
|
|
|
|
if (BUILD_RESOURCES)
|
|
foreach (RESOURCE_FILE ${RESOURCE_FILES})
|
|
string (REGEX MATCH "^[^:]+:::" IS_RESOURCE "${RESOURCE_FILE}")
|
|
if (IS_RESOURCE)
|
|
string (REGEX REPLACE "[^:]+:+" "" RESOURCE_FILE "${RESOURCE_FILE}")
|
|
|
|
get_filename_component (CurrentResource_FileName "${RESOURCE_FILE}" NAME)
|
|
string (REPLACE "." "_" CurrentResource_FileName "${CurrentResource_FileName}")
|
|
set (HEADER_FILE_NAME "${CurrentResource_Directory}_${CurrentResource_FileName}.pxx")
|
|
|
|
set (toProcessResFile TRUE)
|
|
if (isResDirectory)
|
|
list (FIND RESOURCE_FILES "${HEADER_FILE_NAME}" aResIndex)
|
|
if ("${aResIndex}" STREQUAL "-1")
|
|
set (toProcessResFile FALSE)
|
|
endif()
|
|
endif()
|
|
|
|
if (toProcessResFile)
|
|
message(STATUS "Info. Generating header file from resource file: ${CMAKE_SOURCE_DIR}/src/${CurrentResource_Directory}/${RESOURCE_FILE}")
|
|
|
|
# generate content for header file
|
|
set (OCCT_HEADER_FILE_CONTENT "// This file has been automatically generated from resource file src/${CurrentResource_Directory}/${RESOURCE_FILE}\n\n")
|
|
|
|
# read resource file
|
|
file (STRINGS "${CMAKE_SOURCE_DIR}/src/${CurrentResource_Directory}/${RESOURCE_FILE}" RESOURCE_FILE_LINES_LIST)
|
|
|
|
set (OCCT_HEADER_FILE_CONTENT "${OCCT_HEADER_FILE_CONTENT}static const char ${CurrentResource_Directory}_${CurrentResource_FileName}[] =")
|
|
foreach (line IN LISTS RESOURCE_FILE_LINES_LIST)
|
|
string (REPLACE "\"" "\\\"" line "${line}")
|
|
set (OCCT_HEADER_FILE_CONTENT "${OCCT_HEADER_FILE_CONTENT}\n \"${line}\\n\"")
|
|
endforeach()
|
|
set (OCCT_HEADER_FILE_CONTENT "${OCCT_HEADER_FILE_CONTENT};")
|
|
|
|
# Save generated content to header file
|
|
set (HEADER_FILE "${CMAKE_SOURCE_DIR}/src/${CurrentResource_Directory}/${HEADER_FILE_NAME}")
|
|
if (EXISTS "${HEADER_FILE}")
|
|
file (REMOVE "${HEADER_FILE}")
|
|
endif()
|
|
configure_file ("${CMAKE_SOURCE_DIR}/adm/templates/header.in" "${HEADER_FILE}" @ONLY NEWLINE_STYLE LF)
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
endif()
|
|
endmacro()
|
|
|
|
|
|
FILE_TO_LIST ("adm/RESOURCES" RESOURCES)
|
|
foreach (CurrentResource ${RESOURCES})
|
|
get_filename_component (CurrentResource_FileName "${CurrentResource}" NAME)
|
|
if ("${CurrentResource_FileName}" STREQUAL TObj.msg OR
|
|
"${CurrentResource_FileName}" STREQUAL BOPAlgo.msg OR
|
|
"${CurrentResource_FileName}" STREQUAL Units.dat OR
|
|
"${CurrentResource}" STREQUAL XSMessage OR
|
|
"${CurrentResource}" STREQUAL SHMessage OR
|
|
"${CurrentResource}" STREQUAL Shaders)
|
|
OCCT_GENERATE_CONTENT_ONLY ("${CurrentResource}")
|
|
endif()
|
|
endforeach()
|