mirror of
https://git.dev.opencascade.org/repos/occt.git
synced 2025-04-02 17:46:22 +03:00
b8db9379fe
Added TKOpenGlTest and TKD3DHostTest Draw Harness plugins. TKOpenGlTest is automatically loaded by ViewerTest::ViewerInit(). Commands vgldebug, vvbo, vcaps and vuserdraw have been moved to TKOpenGlTest. New command vglshaders lists GLSL programs defined by OpenGl_GraphicDriver, previously implemented by "vshaderprog -list". Added new command vdriver for graphic driver selection. Removed erroneous code from command vstereo.
38 lines
1.7 KiB
Plaintext
38 lines
1.7 KiB
Plaintext
# This is a project template file defining an OCCT Module.
|
|
# This project should be included with predefined OCC_MODULE_NAME variable.
|
|
TEMPLATE = subdirs
|
|
exists(custom.auto.pri) { include(custom.auto.pri) }
|
|
exists(custom.pri) { include(custom.pri) }
|
|
|
|
# Iterate over Toolkits within current Module and generate sub-project per Toolkit
|
|
aModuleList = $$cat(../MODULES, lines)
|
|
for (aModuleIter, aModuleList) {
|
|
#aTkList = $$list($$aModuleIter) - this doesn't work, qmake bug?
|
|
aModule = $$first($$list($$aModuleIter))
|
|
equals (aModule, $$OCC_MODULE_NAME) {
|
|
for (aToolKit, $$list($$aModuleIter)) {
|
|
toSkipToolkit = 0
|
|
equals (aToolKit, $$OCC_MODULE_NAME) { toSkipToolkit = 1 }
|
|
!HAVE_VTK:equals (aToolKit, "TKIVtk") { toSkipToolkit = 1 }
|
|
!HAVE_VTK:equals (aToolKit, "TKIVtkDraw") { toSkipToolkit = 1 }
|
|
!win32: equals (aToolKit, "TKD3DHost") { toSkipToolkit = 1 }
|
|
!win32: equals (aToolKit, "TKD3DHostTest") { toSkipToolkit = 1 }
|
|
equals (toSkipToolkit, 0) {
|
|
#warning(aToolKit($$OCC_MODULE_NAME)=$$aToolKit)
|
|
eval(occtkgen_$${aToolKit}.input = $$_PRO_FILE_PWD_/../OccToolkit.pro.in)
|
|
eval(occtkgen_$${aToolKit}.output = $$_PRO_FILE_PWD_/$${aToolKit}/$${aToolKit}.pro)
|
|
eval(occtkgen_$${aToolKit}.config = verbatim)
|
|
eval(QMAKE_SUBSTITUTES += occtkgen_$${aToolKit})
|
|
SUBDIRS += $${aToolKit}
|
|
|
|
aModExtList = $$cat(../../src/$${aToolKit}/EXTERNLIB, lines)
|
|
aTkDepends = $${aToolKit}.depends
|
|
for (aModExtIter, aModExtList) {
|
|
contains ($$list($$aModuleIter), $$aModExtIter) { eval ($${aTkDepends} += $$aModExtIter) }
|
|
}
|
|
#warning($$aToolKit depends on: $$reverse($${aTkDepends}))
|
|
}
|
|
}
|
|
}
|
|
}
|